3874255b9f
* Deploy Self-Signed Certificates for both IPv6 & IPv4 deployments. * Disable IPv6 for RabbitMQ now, for SSL reasons, will be enabled again later in a next iteration. * Deploy Ironic API under WSGI instead of eventlet. * Switch Glance API, Ironic API and Keystone to SSL. * Configure Tempest with SSL endpoints when needed. * Reduce the Ironic tests because of [1]. [1] https://bugs.launchpad.net/ironic/+bug/1554237 Note #1: puppet-swift, and puppet-cinder will require some work to support SSL, so it's not implemented in this patch. Note #2: we don't enable SSL for Neutron because of https://bugs.launchpad.net/neutron/+bug/1514424 Change-Id: Ib2b5289b6f5e82f43cf60dee3152b2c2ddd5a014
54 lines
1.7 KiB
Puppet
54 lines
1.7 KiB
Puppet
class openstack_integration::rabbitmq {
|
|
|
|
include ::openstack_integration::params
|
|
include ::openstack_integration::config
|
|
|
|
case $::osfamily {
|
|
'Debian': {
|
|
$package_provider = 'apt'
|
|
}
|
|
'RedHat': {
|
|
$package_provider = 'yum'
|
|
}
|
|
default: {
|
|
fail("Unsupported osfamily (${::osfamily})")
|
|
}
|
|
}
|
|
|
|
if $::openstack_integration::config::ssl {
|
|
file { '/etc/rabbitmq/ssl/private':
|
|
ensure => directory,
|
|
owner => 'root',
|
|
mode => '0755',
|
|
selinux_ignore_defaults => true,
|
|
before => File["/etc/rabbitmq/ssl/private/${::fqdn}.pem"],
|
|
}
|
|
openstack_integration::ssl_key { 'rabbitmq':
|
|
key_path => "/etc/rabbitmq/ssl/private/${::fqdn}.pem",
|
|
require => File['/etc/rabbitmq/ssl/private'],
|
|
notify => Service['rabbitmq-server'],
|
|
}
|
|
class { '::rabbitmq':
|
|
delete_guest_user => true,
|
|
package_provider => $package_provider,
|
|
ssl => true,
|
|
ssl_only => true,
|
|
ssl_cacert => $::openstack_integration::params::ca_bundle_cert_path,
|
|
ssl_cert => $::openstack_integration::params::cert_path,
|
|
ssl_key => "/etc/rabbitmq/ssl/private/${::fqdn}.pem",
|
|
environment_variables => $::openstack_integration::config::rabbit_env,
|
|
}
|
|
} else {
|
|
class { '::rabbitmq':
|
|
delete_guest_user => true,
|
|
package_provider => $package_provider,
|
|
environment_variables => $::openstack_integration::config::rabbit_env,
|
|
}
|
|
}
|
|
rabbitmq_vhost { '/':
|
|
provider => 'rabbitmqctl',
|
|
require => Class['::rabbitmq'],
|
|
}
|
|
|
|
}
|